Beim umbau meines MZ ETZ 250 gespanns auf ein 15 zoll hinterrad mit PKW bereifung ergab sich folgende frage: Welches kettenritzel soll ich einbauen, die übersetzung wird ja mit dem kleineren rad kürzer?

Die übersetzung ändert sich rechnerisch nach dem verhältnis der abrollumfänge der reifen. Ausganspunkt ist ein 4.0/18 zoll Block-K reifen, dieser hat einen abrollumfang von 2.026 m (laut wbcnet.de/tips/abroll17-21.html). Laut MZ-Forum hat ein 125/15 zoll PKW (enten-) reifen einen abrollumfang von 1.822 m. Daraus ergibt sich ein verhältnis von:

2.026 / 1.822 = 1.112

Das ganze ist dann also ca. 11% kürzer übersetzt. Nur was heisst das nun in der praxis? Um das besser abschätzten zu können, mussten ein paar gangdiagramme her, die dies besser veranschaulichen sollten. Dabei ist sind für mich nur der 4. und 5. gang von interesse, wegen dem kritischen ganganschluss zwischen diesen beiden gängen.

Der informatiker benutzt dazu natürlich kein milimeterpapier sondern ein stück software - am besten eine freie software wie z.b. GnuPlot.

** Vergleich mit dem Original Diagramm aus der Rep. Anleitung **

Zunächst sollte zum vergleich ein gangdiagramm erstellt werden, welches dem des ETZ reparaturhandbuchs entspricht.

Dazu erstellen wir zunächst eine GnuPlot datei die verschiedene konstanten und globale einstellungen für das zeichnen von gangdiagrammen definiert, gang_diagramm_konst.gnuplot:

#
# Definition von konstanten für die erstellung von
# gang-diagrammen ETZ 250
#

#
# Abrollumfang 3.5/18" reifen laut
# http://wbcnet.de/tips/abroll17-21.html
#
Umfang_35_18 = 1.96     # [m]

#
# Abrollumfang 4.0/18" reifen, Block-K
# http://wbcnet.de/tips/abroll17-21.html
#
Umfang_40_18 = 2.026    # [m]

#
# Abrollumfang 125/15" reifen, PKW,
# angabe aus MZ forum
#
Umfang_125_15 = 1.822   # [m]

#
# Gesamtübersetzung 4. gang mit 15-er ritzel:
#
ueb_g4_15 = 2.43*1.048*3.2

#
# Gesamtübersetzung 4. gang mit 16-er ritzel:
#
ueb_g4_16 = 2.43*1.048*3.0

#
# Gesamtübersetzung 4. gang mit 19-er ritzel:
#
ueb_g4_19 = 2.43*1.048*2.52 # = 6.418
ueb_g4_19_db = 6.428        # Aus datenblatt

#
# Gesamtübersetzung 5. gang mit 15-er ritzel:
#
ueb_g5_15 = 2.43*0.87*3.2

#
# Gesamtübersetzung 5. gang mit 16-er ritzel:
#
ueb_g5_16 = 2.43*0.87*3.0

#
# Gesamtübersetzung 5. gang mit 19-er ritzel:
#
ueb_g5_19 = 2.43*0.87*2.52  # = 5.328
ueb_g5_19_db = 5.335        # Aus datenblatt

#
# Definiere funktion zur geschwindigkeits-berechnung, abhängig von
#   * Drehzahl rpm
#   * Abrollumfang umfang
#   * Gesamtübersetzung ueb
#
speed(rpm, umfang, ueb) = (rpm * umfang * 60) / (1000 * ueb)

#
# Drehzahlbereich der gezeichnet werden soll, bereich X-achse
#
set xrange [0:7000]

#
# Einteilung X-achse
#
set xtics 1000
set mxtics 2

#
# Einteilung Y-achse
#
set ytics 10
set mytics 2

#
# Zeichne gitternetzlinien
#
set grid xtics ytics mxtics mytics

#
# Beschriftung diagramm
#
set ylabel "V [km/h]"
set xlabel "N [1/min]"

Um nun ein gangdiagramm zu zeichen starten wir eine interaktive GnuPlot session und geben folgendes ein:

#
# Gangdiagramm ETZ 250 original, reifen 3.5/18, 19-er ritzel
#

load "gang_diagramm_konst.gnuplot"

set title "Gangdiagramm ETZ 250 Solo, Reifen 3.5/18, 19-er Ritzel"

plot \
    speed(x, Umfang_35_18, ueb_g4_19) title "3.5-18\" 4. Gang", \
    speed(x, Umfang_35_18, ueb_g5_19) title "3.5-18\" 5. Gang", \
    speed(5750, Umfang_35_18, ueb_g4_19) title "Anshluss 5750 1/min" lc rgb "brown"

Als ergebnis erhält man dann:

Zum vergleich das original aus dem ETZ rep. handbuch (scan):

Mann erkennt zwei dinge:

  1. Das diagramm ist "umgedreht", d.h. X- und Y-achsen sind vertauscht. Das liegt daran, dass ich die motor-drehzahl als eingangsparameter sehe und diese desshalb auf der X-achse auftrage. Der informationsinhalt ist der gleiche und wer's andersrum haben will kann's ja entsprechend umstellen.
  2. Die geschwindigkeiten im GnuPlot diagramm sind ca. 2% höher als die von MZ angegebenen (z.b. bei 6000 1/min im 5. gang sinds im ersten diagramm ca. 133 km/h, im MZ diagramm ca. 130 km/h). Ich nehme an, bei MZ wurde mit einem anderen abrollumfang des reifens gerechnet!?

Ungereimtheit im Rep. Handbuch

Bezüglich der im handbuch angegebenen übersetzungen ist mir folgendes aufgefallen:

  • Die gesamtübersetzung für die solo ETZ (19-er ritzel, 3.5/18" reifen) im 5. gang ist mit 5.335:1 angegeben.
  • Rechnet man aber primär-, getriebe- und sekundärübersetzung zusammen, so kommt man auf: 2.43 * 0.87 * 2.52 = 5.328:1 ?

Den unterschied von ca. 0.13% kann ich mir nicht erklären - macht aber in der praxis nichts aus, wie das folgende diagramm zeigt, dort sind die verschiedenen werte für jeweils den 4. und 5. gang benutzt worden. Wie man sieht praktisch kein unterschied, die geraden liegen aufeinander:

Zum zeichnen dieses diagramms wurde die folgende steuerdatei (gang_diagramm_etz_orig_db.gnuplot) verwendet:

#
# Gangdiagramm ETZ 250 original, reifen 3.5/18, 19-er ritzel,
# vergleich uebersetzungen aus dem datenblatt.
#

set title "Gangdiagramm Vergleich Uebersetzungen Datenblatt"

load "gang_diagramm_konst.gnuplot"

plot \
    speed(x, Umfang_35_18, ueb_g4_19) title "3.5-18\" 4. Gang", \
    speed(x, Umfang_35_18, ueb_g5_19) title "3.5-18\" 5. Gang", \
    speed(x, Umfang_35_18, ueb_g4_19_db) title "DB 3.5-18\" 4. Gang", \
    speed(x, Umfang_35_18, ueb_g5_19_db) title "DB 3.5-18\" 5. Gang"

Das zeichnen des diagramms erfolgt dann mit folgender kommandozeile (linux-shell):

erwin@venus:~/doc/MZ> gnuplot -p gang_diagramm_etz_orig_db.gnuplot

** Vergleich Reifen 18" Block-K mit 15" PKW Reifen **

Ziel des ganzen war es ja, die überseztungsverhältnisse zwischen der 18" felge mit Block-K reifen und der 15" felge mit 125/135-er PKW reifen zu vergleichen.

Dazu benutzen wir die folgende GnuPlot steuerdatei (gang_diagramm_40_15.gnuplot):

#
# Gangdiagramm vergleich reifen 4.0/18 mit 125/15, 15-er ritzel, ETZ 250
#

load "gang_diagramm_konst.gnuplot"

set title "Gangdiagramm ETZ 250 Vergleich Reifen 4.0/18 mit 125/15 15-er Ritzel (Gespann)"

plot \
    speed(x, Umfang_40_18, ueb_g4_15) title "4.0-18\" 4. Gang" lc rgb "#0000B0" , \
    speed(x, Umfang_40_18, ueb_g5_15) title "4.0-18\" 5. Gang" lc rgb "blue" , \
    speed(x, Umfang_125_15, ueb_g4_15) title "125-15\" 4. Gang" lc rgb "#B00000" , \
    speed(x, Umfang_125_15, ueb_g5_15) title "125-15\" 5. Gang" lc rgb "red", \
    speed(5750, Umfang_40_18, ueb_g4_15) title "Anschluss 4.0, 5750" lc rgb "cyan", \
    speed(5750, Umfang_125_15, ueb_g4_15) title "Anschluss 125, 5750" lc rgb "brown"

Und zeichnen das diagramm mittels:

erwin@venus:~/doc/MZ> gnuplot -p gang_diagramm_40_15.gnuplot

Als ergebnis erhält man dann dieses diagramm:

Die beiden blauen geraden stellen den 4. und 5. gang mit dem Block-K reifen dar. Die beiden roten geraden gelten für die 15" 125-er bereifung. Man erkennt sofort die wesentlich kürzere übersetzung mit dem 15" reifen. Die beiden waagerechten linien stellen den ganganschluss zwischen 4. und 5. gang dar.

Der schaltvorgang wird hier bei einer drehzahl von 5750 U/min angenommen. Beim 18" Block-K reifen erfolgt der schaltvorgang laut diagramm bei ca. 86 Km/h, eine geschwindigkeit, bei der sich das ETZ-Gespann im 5. gang sehr schwer tut. Zumal wir nach dem schaltvorgang bei ca. 4750 U/min im 5. gang wenig leistung zur verfügung haben. Hier bestätigt das diagramm meine praktischen erfahrungen mit dieser reifen/ritzel kombination sehr gut.

Mit dem 15"-er reifen hingegen erfolgt der schaltvorgang bei ca. 77 Km/h, und wir landen bei einer nur unwesentlich höheren drehzahl im 5. gang. Allerdings ist der windwiderstand bei dieser geschwindigkeit wesentlich geringer, so sollte zusammen mit der kürzeren übersetzung ein wesentlich besserer ganganschluss möglich sein.